设置好一些脚本后，调试起来比较方便 。
echo ===== Tftp settings =====
setenv tftpboot_path /tftpboot/at91rm9200/
setenv load_addr 20080000
setenv uboot_file u-boot.bin
setenv uboot_addr 10000000
setenv uboot_size 1ffff
setenv env_file usetenv.img
setenv env_addr 10060000
setenv env_size 1ffff
setenv kernel_file uImage
setenv kernel_addr 10080000
setenv kernel_size 17ffff
setenv ramdisk_file uramdisk
setenv ramdisk_addr 10200000
setenv ramdisk_size 5fffff
setenv write_flash 'tftp ${load_addr} ${tftpboot_path}${file_name};protect off ${file_addr} +${file_size};erase ${file_addr} +${file_size};cp.b ${load_addr} ${file_addr} ${file_size}'
setenv update_uboot 'setenv file_name ${uboot_file};setenv file_addr ${uboot_addr};setenv file_size ${uboot_size};run write_flash'
setenv update_kernel 'setenv file_name ${kernel_file};setenv file_addr ${kernel_addr};setenv file_size ${kernel_size};run write_flash'
setenv update_ramdisk 'setenv file_name ${ramdisk_file};setenv file_addr ${ramdisk_addr};setenv file_size ${ramdisk_size};run write_flash'
setenv update_env 'tftp ${load_addr} ${tftpboot_path}${env_file};autoscr ${load_addr}'
echo ===== Linux Kernel settings =====
setenv kernel_ld_addr 20080000
setenv ramdisk_ld_addr 20410000
setenv load_kernel 'tftp ${kernel_ld_addr} ${tftpboot_path}${kernel_file};'
setenv load_ramdisk 'tftp ${ramdisk_ld_addr} ${tftpboot_path}${ramdisk_file};'
setenv bootargs 'console=ttyS0,115200'
setenv nfs_path '/home/zzc/at91rm9200/rootfs'
setenv ipcfg 'ip=dhcp'
setenv ramargs 'setenv bootargs root=/dev/ram rw'
setenv nfsargs 'setenv bootargs root=/dev/nfs rw nfsroot=${serverip}:${nfs_path} ${ipcfg}'
setenv ram_boot 'run load_kernel load_ramdisk ramargs; bootm ${kernel_ld_addr} ${ramdisk_ld_addr}'
setenv flash_boot 'bootm ${kernel_addr} ${ramdisk_addr}'
setenv nfs_flash 'run nfsargs; bootm ${kernel_addr}'
setenv nfs_ram 'run load_kernel nfsargs; bootm ${kernel_ld_addr}'
setenv bootcmd 'run nfs_ram'
echo ===== Network address settings =====
setenv ipaddr 192.168.200.2
setenv serverip 192.168.200.1
setenv netmask 255.255.255.0
setenv ethaddr 00:45:43:4F:4D:02
echo ===== Save new definitions =====
saveenv
最近又发现在一个更牛的u-boot的脚本，不过，还没怎么仔细看了，先传上来。
http://www.applieddata.net/forums/topic.asp?TOPIC_ID=2024
|