@echo off
echo ==================================================================
echo 使用该脚本前建议先进行杀毒,并在管理员权限下运行该脚本。
echo 脚本将在WINDOWS目录下生成rundl132.exe、logo1_.exe、dll.dll隐藏文件
echo 创建的文件大小为0，如果不是0，可能是木马。
echo created by scz 20061101
echo ==================================================================
echo.
cd /d %windir%
fc logo1_.exe dll.dll >nul 2>&1 && fc rundl132.exe dll.dll >nul 2>&1 && (echo 系统已做过免疫。&goto end)
attrib rundl132.exe -r -h -s >nul 2>&1
del rundl132.exe >nul 2>&1
if exist rundl132.exe (echo 无法删除rundl132.exe,程序可能正在运行，请检查后再运行此脚本。 &goto end)
attrib logo1_.exe -r -h -s >nul 2>&1
del logo1_.exe >nul 2>&1
if exist logo1_.exe (echo 无法删除logo1_.exe,程序可能正在运行，请检查后再运行此脚本。 &goto end)
attrib dll.dll -r -h -s >nul 2>&1
del dll.* >nul 2>&1
if exist dll.dll ren dll.dll "dll.dll%time::=%" >nul 2>&1 || (echo 无法重命名dll.dll,杀毒软件可能防止修改，请检查后再运行此脚本。 &goto end)
copy nul rundl132.exe >nul 2>&1 && (echo 成功创建rundl132.exe) || (echo 无法建立rundl132.exe,可能无权写入，请检查后再运行此脚本。 &goto end)
copy nul logo1_.exe >nul 2>&1 && (echo 成功创建logo1_.exe) || (echo 无法建立logo1_.exe,可能无权写入，请检查后再运行此脚本。 &goto end)
copy nul dll.dll >nul 2>&1 && (echo 成功创建dll.dll) || (echo 无法建立dll.dll,可能无权写入，请检查后再运行此脚本。 &goto end)
attrib rundl132.exe +r +h +s >nul 2>&1
attrib logo1_.exe +r +h +s >nul 2>&1
attrib dll.dll +r +h +s >nul 2>&1
echo.
fc logo1_.exe dll.dll >nul 2>&1 && fc rundl132.exe dll.dll >nul 2>&1 && echo 文件验证通过,免疫程序执行完毕 || echo 文件验整失败，请杀毒...
:end
echo.
echo 请按任意键退出...
pause >nul
|